build.gradle

plugins {
    id 'java'
    id 'groovy'
}

repositories {
    jcenter()
    mavenCentral()
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'java-library'

    test {
        reports.html.enabled = false
        testLogging {
            events "failed"
            exceptionFormat "full"
        }

        if(!project.hasProperty("Legacy")){
            jvmArgs = [
                    '--add-opens', 'java.base/java.lang.reflect=ALL-UNNAMED'
            ]
        }
    }

    ext {
        id = 'TriggerReactor'
        version = '3.2.3'
        description = 'Simple script parser with infinite possibility'
        author = 'wysohn'
        authors = [
                'soliddanii',
                'MidnightSugar',
                'TheBestNightSky',
                'dltks0306',
                'RubrumExPlaneta',
                'Alex4386',
                'RedLime',
                'mrandriyg',
                'professer_snape',
                'gerzytet',
                'Kuiprux'
        ]
    }


    sourceSets {
        main {
            java {
                srcDirs = ['src/main/java']
            }
            resources {
                srcDirs = ['src/main/resources']
                include '**/*.js'
                include '**/*.yml'
            }
        }

        test {
            java {
                srcDirs = ['src/test/java/']
            }
        }
    }

    repositories {
        jcenter()
        mavenCentral()
    }

    dependencies {
        // https://mvnrepository.com/artifact/mysql/mysql-connector-java
        api group: 'mysql', name: 'mysql-connector-java', version: '5.1.13'
        // https://mvnrepository.com/artifact/mysql/mysql-connector-java
        api group: 'mysql', name: 'mysql-connector-java', version: '5.1.13'
        // https://mvnrepository.com/artifact/org.apache.commons/commons-lang3
        api group: 'org.apache.commons', name: 'commons-lang3', version: '3.12.0'

        // https://mvnrepository.com/artifact/org.graalvm.js/js
        //implementation group: 'org.graalvm.js', name: 'js', version: '21.1.0'
        // https://mvnrepository.com/artifact/org.graalvm.js/js-scriptengine
        //implementation group: 'org.graalvm.js', name: 'js-scriptengine', version: '21.1.0'

        testImplementation 'junit:junit:4.11'
        testImplementation 'org.mockito:mockito-core:3.11.2'
//        testImplementation 'org.powermock:powermock-core:2.+'
//        testImplementation 'org.powermock:powermock-module-junit4:2.+'
//        testImplementation 'org.powermock:powermock-api-mockito2:2.+'
        testImplementation 'org.javassist:javassist:3.20.0-GA'
    }

    java{
        sourceCompatibility = JavaVersion.VERSION_16
        targetCompatibility = JavaVersion.VERSION_16
    }

    task copyResources(type: Copy) {
        from project(":core").sourceSets.main.output.resourcesDir
        into "${buildDir}/resources/main"
    }
    jar.dependsOn copyResources

    task copyJars(type: Copy) {
        from project.file('build/libs')
        include '*.jar'
        into rootProject.file('build/libs')
    }

    build.finalizedBy(copyJars)

    javadoc {
        failOnError false
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
        options.addStringOption('charSet', 'UTF-8')

        exclude "**/copy/com/google/**"
        exclude "org/apache/**"
    }
}

allprojects {
    task testLegacy{
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    testLegacy.finalizedBy test
}

def exportedProjects= [
        ":core",
        /*":sponge",*/
        ":bukkit",
        ":bukkit:legacy",
        ":bukkit:latest"
]

javadoc {
    failOnError false
    options.addStringOption('Xdoclint:none', '-quiet')
    options.addStringOption('encoding', 'UTF-8')
    options.addStringOption('charSet', 'UTF-8')

    source exportedProjects.collect { project(it).sourceSets.main.allJava }
    classpath = files(exportedProjects.collect { project(it).sourceSets.main.compileClasspath })
    options {
        links "https://docs.oracle.com/javase/8/docs/api/"
        links "https://hub.spigotmc.org/javadocs/bukkit/"
        links "https://jd.spongepowered.org/7.0.0/"
    }
    destinationDir = file("${buildDir}/docs/javadoc")
    exclude "**/copy/com/google/**"
    exclude "org/apache/**"
}