build.gradle

apply plugin: "java"
apply plugin: "application"
apply plugin: "com.github.johnrengelman.shadow"

mainClassName = 'com.terminalvelocitycabbage.exampleclient.GameClient'

jar {
	manifest {
		attributes('Main-Class': mainClassName)
	}
}

buildscript {
	repositories {
		maven {
			url "https://plugins.gradle.org/m2/"
		}
	}
	dependencies {
		classpath "com.github.jengelman.gradle.plugins:shadow:5.2.0"
	}
}

switch (org.gradle.internal.os.OperatingSystem.current()) {
	case org.gradle.internal.os.OperatingSystem.LINUX:
		def osArch = System.getProperty("os.arch")
		project.ext.lwjglNatives = osArch.startsWith("arm") || osArch.startsWith("aarch64")
				? "natives-linux-${osArch.contains("64") || osArch.startsWith("armv8") ? "arm64" : "arm32"}"
				: "natives-linux"
		break
	case org.gradle.internal.os.OperatingSystem.MAC_OS:
		project.ext.lwjglNatives = "natives-macos"
		break
	case org.gradle.internal.os.OperatingSystem.WINDOWS:
		project.ext.lwjglNatives = System.getProperty("os.arch").contains("64") ? "natives-windows" : "natives-windows-x86"
		break
}

repositories {
	mavenCentral()
}

project.ext.lwjglVersion = "3.2.3"
project.ext.jomlVersion = "1.9.22"

dependencies {
	implementation platform("org.lwjgl:lwjgl-bom:$lwjglVersion")

	implementation "org.lwjgl:lwjgl"
	implementation "org.lwjgl:lwjgl-assimp"
	implementation "org.lwjgl:lwjgl-glfw"
	implementation "org.lwjgl:lwjgl-openal"
	implementation "org.lwjgl:lwjgl-opencl"
	implementation "org.lwjgl:lwjgl-opengl"
	implementation "org.lwjgl:lwjgl-shaderc"
	implementation "org.lwjgl:lwjgl-stb"
	runtimeOnly "org.lwjgl:lwjgl::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-assimp::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-glfw::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-openal::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-opengl::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-shaderc::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-stb::$lwjglNatives"
	implementation "org.joml:joml:${jomlVersion}"

	implementation 'com.github.jhg023:SimpleNet:1.6.4'

	implementation project('terminal_velocity_engine')
	implementation project('studio_jar')

	implementation group: 'org.fusesource.jansi', name: 'jansi', version: '1.8'
	implementation group: 'commons-io', name: 'commons-io', version: '2.5'
}