build.gradle

plugins {
    id "java"
    id "checkstyle"
}

base {
    java.toolchain.languageVersion = JavaLanguageVersion.of(17)
    compileJava.options.encoding = compileTestJava.options.encoding = javadoc.options.encoding = "UTF-8"

    archivesName = project.maven_name ?: rootProject.maven_name
    group = project.maven_group ?: rootProject.maven_group
    version = project.maven_version ?: rootProject.maven_version
}

repositories {
    mavenCentral()
    maven {
        name = "viaversion"
        url = "https://repo.viaversion.com/everything"
    }
}

dependencies {
    compileOnly "com.google.code.findbugs:jsr305:3.0.2"
    compileOnly "org.jetbrains:annotations:26.0.1"
    compileOnly(annotationProcessor("org.projectlombok:lombok:1.18.36"))
    compileOnly "net.raphimc:ViaProxy:3.3.8-SNAPSHOT"
}

processResources {
    //Config file: "version: ${version}"
    inputs.properties(
            "version": project.maven_version
    )

    filesMatching("viaproxy.yml") {
        expand(
                "version": project.maven_version
        )
    }
}

checkstyle {
    toolVersion = "10.16.0" //Latest version for Java 8: 9.3
    configFile = rootProject.file("config/checkstyle/checkstyle.xml")
}

build.dependsOn(check)