How to export k8s mainfests?

[aloifolia]

I'm currently evaluating the feasibility of replacing Kustomize with Cuelang in our project. Unfortunately, I'm stumbling quite early. According to this guide, you define your k8s objects like this:

service: [string]:     core.#Service
deployment: [string]:  apps.#Deployment
daemonSet: [string]:   apps.#DaemonSet
statefulSet: [string]: apps.#StatefulSet

So, all definitions are nested in some kind of "struct" (my terminology is certainly off, here). The guide then shows how to export everything to yaml:

$ cue export --out yaml
service: {}
deployment: {}
daemonSet: {}
statefulSet: {}

Of course, all entries are empty because I did not really define anything specific. But my question is: Given that there was some actual content - how would I extract all nested configurations so that I get a ready to use (by kubectl) list of manifests?

[DavidGamba]

Add a dump_tool.cue file where you have your multi-document yaml file:

package p

// https://cuetorials.com/first-steps/import-configuration/
// cue import -f -o data.cue -l 'data:' -l 'strings.ToLower(kind)' -l 'metadata.name' -p p input.yaml

// cue cmd dump

import (
        "encoding/yaml"
        "tool/cli"
        "list"
)

data_list: [
        for k, v in data {
                [for k2, v2 in v {
                        v2
                }]
        }
]

command: dump: {
        task: print: cli.Print & {
                text: yaml.MarshalStream(list.FlattenN(data_list, -1))
        }
}

Run: cue import -f -o data.cue -l 'data:' -l 'strings.ToLower(kind)' -l 'metadata.name' -p p input.yaml
To import your Yaml into a struct of structs.

Run: cue cmd dump to dump it back.

The trick is in the MarshalStream and in converting your structs into a list.

The kubernetes tutorial has something along the lines of:

objects: [for v in objectSets for x in v {x}]

objectSets: [
	namespace,
	networkPolicy,
	secretStore,
	externalSecret,
	pushSecret,
	serviceAccount,
	role,
	roleBinding,
	clusterRoleBinding,
	eventBus,
	eventSource,
	podDisruptionBudget,
	service,
	ingress,
	issuer,
	certificate,
]

To create the list.

[hansbogert]

I'm using timoni as a kustomize replacement. It uses cue but is a bit more opinionated so you don't feel you're reinventing the wheel.

https://timoni.sh