build.gradle

buildscript {
    ext{
        odcPluginVersion = project.hasProperty('odcGradlePluginVersion') ? project.getProperty('odcGradlePluginVersion') : '10.0.3'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.owasp:dependency-check-gradle:$odcPluginVersion"
    }
}

apply plugin: 'java'
apply plugin: 'org.owasp.dependencycheck'

group 'eu.righettod'
version '2.0.1'
def burpExtensionHomepage = 'https://github.com/righettod/log-requests-to-sqlite'
def burpExtensionJarName = 'LogRequestsToSQLite.jar'

repositories {
    mavenCentral()
}

dependencies {
    compile 'org.xerial:sqlite-jdbc:3.47.0.0'
    compile 'net.portswigger.burp.extender:burp-extender-api:2.3'
}

sourceSets {
    main {
        java {
            srcDir 'src'
        }
        resources {
            srcDir 'resources'
        }
    }
}

compileJava {
    targetCompatibility '11'
    sourceCompatibility '11'
}

dependencyCheck {
    autoUpdate = true
    failOnError = true
    failBuildOnCVSS = 1
    cveValidForHours = 12
    suppressionFile = "odc-suppress.xml"
    format = 'JSON'
}

task fatJar(type: Jar) {
    manifest {
        attributes("Implementation-Version": project.version, "Implementation-Title": project.name, "Implementation-URL": burpExtensionHomepage)
    }
    archiveName = burpExtensionJarName
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}