build.gradle

plugins {
    id 'maven-publish'
    id 'signing'
}

apply plugin: 'scala'
apply plugin: 'java-library'

group 'com.sbuslab'

repositories {
    maven { url 'https://oss.sonatype.org/content/repositories/public' }
    mavenCentral()
}

java {
    withJavadocJar()
    withSourcesJar()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'model'
            from components.java

            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }

            pom {
                name = 'model'
                description = 'Tools for akka-http (marshaling, error handling, websockets, sbus support)'
                url = 'https://github.com/sbuslab/model'
                inceptionYear = '2018'

                licenses {
                    license {
                        name = 'The Apache Software License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'repo'
                    }
                }

                developers {
                    developer {
                        id = 'kulikovd'
                        name = 'Dmitry Kulikov'
                        email = 'kulikov.dm@gmail.com'
                    }
                }

                scm {
                    url = 'https://github.com/sbuslab/model'
                    connection = 'scm:https://github.com/sbuslab/model.git'
                    developerConnection = 'scm:git@github.com:sbuslab/model.git'
                }
            }
        }
    }

    if (project.findProperty('publishSonatype')) {
        repositories {
            maven {
                url = "https://oss.sonatype.org/service/local/staging/deploy/maven2"

                credentials {
                    username = project.findProperty('nexusUsername') ?: ''
                    password = project.findProperty('nexusPassword') ?: ''
                }
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}

dependencies {
    api 'org.scala-lang:scala-library:2.12.16'
    api 'org.scala-lang.modules:scala-java8-compat_2.12:1.0.2'

    api 'org.projectlombok:lombok:1.18.24'
    annotationProcessor 'org.projectlombok:lombok:1.18.24'

    api 'org.hibernate:hibernate-validator:6.2.3.Final'
    api 'org.glassfish:jakarta.el:3.0.4'

    api 'com.fasterxml.jackson.core:jackson-databind:2.13.4'
}