forked from namin/dafny-sandbox
-
Notifications
You must be signed in to change notification settings - Fork 0
/
LnSystemF.dfy
1736 lines (1648 loc) · 56.2 KB
/
LnSystemF.dfy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/// Utilities
datatype option<A> = None | Some(get: A);
function chain(a: option, b: option): option
ensures a.None? ==> chain(a, b)==b;
ensures a.Some? ==> chain(a, b)==a;
ensures chain(a, b)==a || chain(a, b)==b;
ensures chain(a, b).Some? <==> (a.Some? || b.Some?);
{
if (a.None?) then b else a
}
function notin(s: set<int>): int
ensures notin(s) !in s;
{
notin_rec(s, 0, {}, s)
}
function notin_rec(s: set<int>, r: nat, sr: set<int>, so: set<int>): nat
requires forall x :: x in sr ==> x<=r;
requires s+sr==so;
ensures notin_rec(s, r, sr, so) !in so;
{
if (!exists x :: x in s) then r+1 else
var x :| x in s;
if (x<r) then notin_rec(s-{x}, r, sr+{x}, so) else notin_rec(s-{x}, x, sr+{x}, so)
}
/// Definition of System F
/// https://github.com/plclub/metalib/blob/master/Fsub_LetSum_Definitions.v
datatype typ =
typ_top
| typ_bvar(n: nat)
| typ_fvar(a: int)
| typ_arrow(ty1: typ, ty2: typ)
| typ_all(ty0: typ)
datatype exp =
exp_bvar(n: nat)
| exp_fvar(a: int)
| exp_abs(ty: typ, e0: exp)
| exp_app(f: exp, arg: exp)
| exp_tabs(te0: exp)
| exp_tapp(tf: exp, targ: typ)
function typ_size(T: typ): nat
{
match T
case typ_top => 1
case typ_bvar(J) => 1
case typ_fvar(X) => 1
case typ_arrow(T1, T2) => 1+typ_size(T1)+typ_size(T2)
case typ_all(T1) => 1+typ_size(T1)
}
function exp_size(e: exp): nat
{
match e
case exp_bvar(i) => 1
case exp_fvar(x) => 1
case exp_abs(V, e1) => 1+typ_size(V)+exp_size(e1)
case exp_app(e1, e2) => 1+exp_size(e1)+exp_size(e2)
case exp_tabs(e1) => 1+exp_size(e1)
case exp_tapp(e1, V) => 1+exp_size(e1)+typ_size(V)
}
function open_tt_rec(K : nat, U : typ, T : typ): typ
ensures U.typ_fvar? ==> typ_size(T)==typ_size(open_tt_rec(K, U, T));
decreases T;
{
match T
case typ_top => typ_top
case typ_bvar(J) => if K == J then U else typ_bvar(J)
case typ_fvar(X) => typ_fvar(X)
case typ_arrow(T1, T2) => typ_arrow(open_tt_rec(K, U, T1), open_tt_rec(K, U, T2))
case typ_all(T1) => typ_all(open_tt_rec(K+1, U, T1))
}
function open_te_rec(K : nat, U : typ, e : exp): exp
ensures U.typ_fvar? ==> exp_size(e)==exp_size(open_te_rec(K, U, e));
decreases e;
{
match e
case exp_bvar(i) => exp_bvar(i)
case exp_fvar(x) => exp_fvar(x)
case exp_abs(V, e1) => exp_abs(open_tt_rec(K, U, V), open_te_rec(K, U, e1))
case exp_app(e1, e2) => exp_app(open_te_rec(K, U, e1), open_te_rec(K, U, e2))
case exp_tabs(e1) => exp_tabs(open_te_rec(K+1, U, e1))
case exp_tapp(e1, V) => exp_tapp(open_te_rec(K, U, e1), open_tt_rec(K, U, V))
}
function open_ee_rec(k : nat, f : exp, e : exp): exp
ensures f.exp_fvar? ==> exp_size(e)==exp_size(open_ee_rec(k, f, e));
decreases e;
{
match e
case exp_bvar(i) => if k == i then f else exp_bvar(i)
case exp_fvar(x) => exp_fvar(x)
case exp_abs(V, e1) => exp_abs(V, open_ee_rec(k+1, f, e1))
case exp_app(e1, e2) => exp_app(open_ee_rec(k, f, e1),open_ee_rec(k, f, e2))
case exp_tabs(e1) => exp_tabs(open_ee_rec(k, f, e1))
case exp_tapp(e1, V) => exp_tapp(open_ee_rec(k, f, e1), V)
}
function open_tt(T: typ, U: typ): typ { open_tt_rec(0, U, T) }
function open_te(e: exp, U: typ): exp { open_te_rec(0, U, e) }
function open_ee(e1: exp, e2: exp): exp { open_ee_rec(0, e2, e1) }
predicate typ_lc(T: typ)
decreases typ_size(T);
{
match T
case typ_top => true
case typ_bvar(J) => false
case typ_fvar(X) => true
case typ_arrow(T1, T2) => typ_lc(T1) && typ_lc(T2)
case typ_all(T1) => exists L:set<int> :: forall X :: X !in L ==> typ_lc(open_tt(T1, typ_fvar(X)))
}
predicate exp_lc(e: exp)
decreases exp_size(e);
{
match e
case exp_bvar(i) => false
case exp_fvar(x) => true
case exp_abs(V, e1) => typ_lc(V) && (exists L:set<int> :: forall x :: x !in L ==> exp_lc(open_ee(e1, exp_fvar(x))))
case exp_app(e1, e2) => exp_lc(e1) && exp_lc(e2)
case exp_tabs(e1) => exists L:set<int> :: forall X :: X !in L ==> exp_lc(open_te(e1, typ_fvar(X)))
case exp_tapp(e1, V) => exp_lc(e1) && typ_lc(V)
}
predicate body_lc(e: exp)
{
exists L:set<int> :: forall x :: x !in L ==> exp_lc(open_ee(e, exp_fvar(x)))
}
datatype binding =
bd_typ(x: int, ty: typ)
| bd_var(X: int)
function var_name(bd: binding): int
ensures bd.bd_var? ==> var_name(bd)==bd.X;
ensures bd.bd_typ? ==> var_name(bd)==bd.x;
{
match bd
case bd_typ(x, T) => x
case bd_var(X) => X
}
datatype env = Env(bds: seq<binding>)
function env_plus_var(X: int, E: env): env
{
Env([bd_var(X)]+E.bds)
}
predicate env_has_var(X: int, E: env)
{
bd_var(X) in E.bds
}
function env_extend(x: int, T: typ, E: env): env
{
Env([bd_typ(x, T)]+E.bds)
}
function env_lookup(x: int, E: env): option<typ>
ensures env_lookup(x, E).Some? ==> bd_typ(x, env_lookup(x, E).get) in E.bds;
{
bds_lookup(x, E.bds)
}
function bds_lookup(x: int, bds: seq<binding>): option<typ>
ensures bds_lookup(x, bds).Some? ==> |bds|>0;
ensures bds_lookup(x, bds).Some? ==> (bd_lookup(x, bds[0]).Some? || bds_lookup(x, bds[1..]).Some?);
ensures bds_lookup(x, bds).Some? ==> bd_typ(x, bds_lookup(x, bds).get) in bds;
{
if |bds|==0 then None else chain(bd_lookup(x, bds[0]), bds_lookup(x, bds[1..]))
}
function bd_lookup(y: int, bd: binding): option<typ>
ensures bd_lookup(y, bd).Some? ==> (bd.bd_typ? && bd.x==y);
{
match bd
case bd_typ(x, T) => if x==y then Some(T) else None
case bd_var(X) => None
}
function env_concat(E1: env, E2: env): env
{
Env(E1.bds+E2.bds)
}
function env_concat3(E1: env, E2: env, E3: env): env
{
Env(E1.bds+E2.bds+E3.bds)
}
predicate typ_wf(E: env, T: typ)
decreases typ_size(T);
{
match T
case typ_top => true
case typ_bvar(J) => false
case typ_fvar(X) => env_has_var(X, E)
case typ_arrow(T1, T2) => typ_wf(E, T1) && typ_wf(E, T2)
case typ_all(T1) => exists L:set<int> :: forall X :: X !in L ==> typ_wf(env_plus_var(X, E), open_tt(T1, typ_fvar(X)))
}
function bd_dom(bd: binding): set<int>
{
match bd
case bd_typ(x, T) => {x}
case bd_var(X) => {X}
}
function bds_dom(bds: seq<binding>): set<int>
ensures forall X :: bd_var(X) in bds ==> X in bds_dom(bds);
{
if |bds|==0 then {} else bd_dom(bds[0])+bds_dom(bds[1..])
}
function env_dom(E: env): set<int>
ensures forall X :: env_has_var(X, E) ==> X in env_dom(E);
{
bds_dom(E.bds)
}
predicate bds_wf(bds: seq<binding>)
ensures bds_wf(bds) ==> bds_uniq(bds);
decreases bds, 0;
{
|bds|==0 || (
var bds' := bds[1..];
bds_wf(bds') && bd_wf(bds[0], bds')
)
}
predicate bd_wf(bd: binding, bds: seq<binding>)
requires bds_wf(bds);
ensures bd_wf(bd, bds) ==> bd_uniq(bd, bds_dom(bds));
decreases bds, 1;
{
match bd
case bd_typ(x, T) => typ_wf(Env(bds), T) && x !in bds_dom(bds)
case bd_var(X) => X !in bds_dom(bds)
}
predicate env_wf(E: env)
ensures env_wf(E) ==> env_uniq(E);
{
bds_wf(E.bds)
}
predicate bds_uniq(bds: seq<binding>)
ensures (bds_uniq(bds) && |bds|>0) ==> bd_uniq(bds[0], bds_dom(bds[1..]));
ensures (bds_uniq(bds) && |bds|>0 && bds[0].bd_var?) ==> bds[0].X !in bds_dom(bds[1..]);
ensures (bds_uniq(bds) && |bds|>0 && bds[0].bd_typ?) ==> bds[0].x !in bds_dom(bds[1..]);
decreases |bds|;
{
|bds|==0 || (
var bds' := bds[1..];
bds_uniq(bds') && bd_uniq(bds[0], bds_dom(bds'))
)
}
predicate bd_uniq(bd: binding, dom_bds: set<int>)
ensures bd.bd_typ? ==> (bd.x !in dom_bds <==> bd_uniq(bd, dom_bds));
ensures bd.bd_var? ==> (bd.X !in dom_bds <==> bd_uniq(bd, dom_bds));
{
match bd
case bd_typ(x, T) => x !in dom_bds
case bd_var(X) => X !in dom_bds
}
predicate env_uniq(E: env)
{
bds_uniq(E.bds)
}
predicate typing(E: env, e: exp, T: typ)
decreases exp_size(e);
{
match e
case exp_bvar(i) => false
case exp_fvar(x) => env_wf(E) && env_lookup(x, E)==Some(T)
case exp_abs(V, e1) => T.typ_arrow? &&
T.ty1==V && (exists L:set<int> :: forall x :: x !in L ==> typing(env_extend(x, V, E), open_ee(e1, exp_fvar(x)), T.ty2))
case exp_app(e1, e2) => exists T1 :: typing(E, e1, typ_arrow(T1, T)) && typing(E, e2, T1)
case exp_tabs(e1) => T.typ_all? &&
(exists L:set<int> :: forall X :: X !in L ==> typing(env_plus_var(X, E), open_te(e1, typ_fvar(X)), open_tt(T.ty0, typ_fvar(X))))
case exp_tapp(e1, T2) => exists T1 :: typing(E, e1, T1) && T1.typ_all? && typ_wf(E, T2) && open_tt(T1.ty0, T2)==T
}
predicate value(e: exp)
{
match e
case exp_abs(V, e1) => exp_lc(e)
case exp_tabs(e1) => exp_lc(e)
case exp_bvar(i) => false
case exp_fvar(x) => false
case exp_app(e1, e2) => false
case exp_tapp(e1, V) => false
}
function red(e: exp): option<exp>
{
// red_app_1
if (e.exp_app? && exp_lc(e.arg) && red(e.f).Some?) then
Some(exp_app(red(e.f).get, e.arg))
// red_app_2
else if (e.exp_app? && value(e.f) && red(e.arg).Some?) then
Some(exp_app(e.f, red(e.arg).get))
// red_tapp
else if (e.exp_tapp? && typ_lc(e.targ) && red(e.tf).Some?) then
Some(exp_tapp(red(e.tf).get, e.targ))
// red_abs
else if (e.exp_app? && value(e.f) && value(e.arg) && e.f.exp_abs?) then
Some(open_ee(e.f.e0, e.arg))
// red_tabs
else if (e.exp_tapp? && value(e.tf) && typ_lc(e.targ) && e.tf.exp_tabs?) then
Some(open_te(e.tf.te0, e.targ))
else None
}
/// Infrastructure
/// https://github.com/plclub/metalib/blob/master/Fsub_LetSum_Infrastructure.v
function fv_tt(T: typ): set<int>
{
match T
case typ_top => {}
case typ_bvar(J) => {}
case typ_fvar(X) => {X}
case typ_arrow(T1, T2) => fv_tt(T1) + fv_tt(T2)
case typ_all(T1) => fv_tt(T1)
}
function fv_te(e: exp): set<int>
{
match e
case exp_bvar(i) => {}
case exp_fvar(x) => {}
case exp_abs(V, e1) => fv_tt(V) + fv_te(e1)
case exp_app(e1, e2) => fv_te(e1) + fv_te(e2)
case exp_tabs(e1) => fv_te(e1)
case exp_tapp(e1, V) => fv_tt(V) + fv_te(e1)
}
function fv_ee(e: exp): set<int>
{
match e
case exp_bvar(i) => {}
case exp_fvar(x) => {x}
case exp_abs(V, e1) => fv_ee(e1)
case exp_app(e1, e2) => fv_ee(e1) + fv_ee(e2)
case exp_tabs(e1) => fv_ee(e1)
case exp_tapp(e1, V) => fv_ee(e1)
}
function subst_tt (Z: int, U: typ, T : typ): typ
decreases T;
{
match T
case typ_top => typ_top
case typ_bvar(J) => typ_bvar(J)
case typ_fvar(X) => if X == Z then U else T
case typ_arrow(T1, T2) => typ_arrow(subst_tt(Z, U, T1), subst_tt(Z, U, T2))
case typ_all(T1) => typ_all(subst_tt(Z, U, T1))
}
function subst_te(Z: int, U: typ, e : exp): exp
decreases e;
{
match e
case exp_bvar(i) => exp_bvar(i)
case exp_fvar(x) => exp_fvar(x)
case exp_abs(V, e1) => exp_abs(subst_tt(Z, U, V),subst_te(Z, U, e1))
case exp_app(e1, e2) => exp_app(subst_te(Z, U, e1), subst_te(Z, U, e2))
case exp_tabs(e1) => exp_tabs(subst_te(Z, U, e1))
case exp_tapp(e1, V) => exp_tapp(subst_te(Z, U, e1), subst_tt(Z, U, V))
}
function subst_ee(z: int, u: exp, e: exp): exp
decreases e;
{
match e
case exp_bvar(i) => exp_bvar(i)
case exp_fvar(x) => if x == z then u else e
case exp_abs(V, e1) => exp_abs(V, subst_ee(z, u, e1))
case exp_app(e1, e2) => exp_app(subst_ee(z, u, e1), subst_ee(z, u, e2))
case exp_tabs(e1) => exp_tabs(subst_ee(z, u, e1))
case exp_tapp(e1, V) => exp_tapp(subst_ee(z, u, e1), V)
}
ghost method {:induction T, j, i} lemma_open_tt_rec_type_aux(T: typ, j: nat, V: typ, i: nat, U: typ)
requires i != j;
requires open_tt_rec(j, V, T) == open_tt_rec(i, U, open_tt_rec(j, V, T));
ensures T == open_tt_rec(i, U, T);
{
}
ghost method lemma_open_tt_rec_type(T: typ, U: typ, k: nat)
requires typ_lc(T);
ensures T == open_tt_rec(k, U, T);
decreases typ_size(T);
{
if (T.typ_all?) {
var L:set<int> :| forall X :: X !in L ==> typ_lc(open_tt(T.ty0, typ_fvar(X)));
var X := notin(L);
lemma_open_tt_rec_type(open_tt(T.ty0, typ_fvar(X)), U, k+1);
lemma_open_tt_rec_type_aux(T.ty0, 0, typ_fvar(X), k+1, U);
}
}
ghost method lemma_subst_tt_fresh(Z: int, U: typ, T: typ)
requires Z !in fv_tt(T);
ensures T == subst_tt(Z, U, T);
{
}
ghost method lemma_subst_tt_open_tt_rec(T1: typ, T2: typ, X: int, P: typ, k: nat)
requires typ_lc(P);
ensures subst_tt(X, P, open_tt_rec(k, T2, T1))
== open_tt_rec(k, subst_tt(X, P, T2), subst_tt(X, P, T1));
{
if (T1.typ_fvar? && T1.a==X) {
lemma_open_tt_rec_type(P, subst_tt(X, P, T2), k);
}
}
ghost method lemma_subst_tt_open_tt(T1: typ, T2: typ, X: int, P: typ)
requires typ_lc(P);
ensures subst_tt(X, P, open_tt(T1, T2)) == open_tt(subst_tt(X, P, T1), subst_tt(X, P, T2));
{
lemma_subst_tt_open_tt_rec(T1, T2, X, P, 0);
}
ghost method lemma_subst_tt_open_tt_var(X: int, Y: int, P: typ, T: typ)
requires Y != X;
requires typ_lc(P);
ensures open_tt(subst_tt(X, P, T), typ_fvar(Y)) == subst_tt(X, P, open_tt(T, typ_fvar(Y)));
{
lemma_subst_tt_open_tt(T, typ_fvar(Y), X, P);
}
ghost method lemma_subst_tt_intro_rec(X: int, T2: typ, U: typ, k: nat)
requires X !in fv_tt(T2);
ensures open_tt_rec(k, U, T2) == subst_tt(X, U, open_tt_rec(k, typ_fvar(X), T2));
{
}
ghost method lemma_subst_tt_intro(X: int, T2: typ, U: typ)
requires X !in fv_tt(T2);
ensures open_tt(T2, U) == subst_tt(X, U, open_tt(T2, typ_fvar(X)));
{
lemma_subst_tt_intro_rec(X, T2, U, 0);
}
ghost method {:induction e, j, i} lemma_open_te_rec_expr_aux(e: exp, j: nat, u: exp, i: nat, P: typ)
requires open_ee_rec(j, u, e) == open_te_rec(i, P, open_ee_rec(j, u, e));
ensures e == open_te_rec(i, P, e);
{
}
ghost method {:induction e, j, i} lemma_open_te_rec_type_aux(e: exp, j: nat, Q: typ, i: nat, P: typ)
requires i != j;
requires open_te_rec(j, Q, e) == open_te_rec(i, P, open_te_rec(j, Q, e));
ensures e == open_te_rec(i, P, e);
{
forall (V | i !=j && open_tt_rec(j, Q, V) == open_tt_rec(i, P, open_tt_rec(j, Q, V)))
ensures V == open_tt_rec(i, P, V);
{
lemma_open_tt_rec_type_aux(V, j, Q, i, P);
}
}
ghost method lemma_open_te_rec_expr(e: exp, U: typ, k: nat)
requires exp_lc(e);
ensures e == open_te_rec(k, U, e);
decreases exp_size(e);
{
forall (V | typ_lc(V))
ensures V == open_tt_rec(k, U, V);
{
lemma_open_tt_rec_type(V, U, k);
}
if (e.exp_abs?) {
var L:set<int> :| forall x :: x !in L ==> exp_lc(open_ee(e.e0, exp_fvar(x)));
var x := notin(L);
lemma_open_te_rec_expr(open_ee(e.e0, exp_fvar(x)), U, k);
lemma_open_te_rec_expr_aux(e.e0, 0, exp_fvar(x), k, U);
} else if (e.exp_tabs?) {
var L:set<int> :| forall X :: X !in L ==> exp_lc(open_te(e.te0, typ_fvar(X)));
var X := notin(L);
lemma_open_te_rec_type_aux(e.te0, 0, typ_fvar(X), k+1, U);
}
}
ghost method lemma_subst_te_fresh(X: int, U: typ, e: exp)
requires X !in fv_te(e);
ensures e == subst_te(X, U, e);
{
forall (T | X !in fv_tt(T))
ensures T == subst_tt(X, U, T);
{
lemma_subst_tt_fresh(X, U, T);
}
}
ghost method lemma_subst_te_open_te_rec(e: exp, T: typ, X: int, U: typ, k: nat)
requires typ_lc(U);
ensures subst_te(X, U, open_te_rec(k, T, e))
== open_te_rec(k, subst_tt(X, U, T), subst_te(X, U, e));
{
forall (V | V<e)
ensures subst_tt(X, U, open_tt_rec(k, T, V))
== open_tt_rec(k, subst_tt(X, U, T), subst_tt(X, U, V));
{
lemma_subst_tt_open_tt_rec(V, T, X, U, k);
}
}
ghost method lemma_subst_te_open_te(e: exp, T: typ, X: int, U: typ)
requires typ_lc(U);
ensures subst_te(X, U, open_te(e, T)) == open_te(subst_te(X, U, e), subst_tt(X, U, T));
{
lemma_subst_te_open_te_rec(e, T, X, U, 0);
}
ghost method lemma_subst_te_open_te_var(X: int, Y: int, U: typ, e: exp)
requires Y != X;
requires typ_lc(U);
ensures open_te(subst_te(X, U, e), typ_fvar(Y)) == subst_te(X, U, open_te(e, typ_fvar(Y)));
{
lemma_subst_te_open_te(e, typ_fvar(Y), X, U);
}
ghost method lemma_subst_te_intro_rec(X: int, e: exp, U: typ, k: nat)
requires X !in fv_te(e);
ensures open_te_rec(k, U, e) == subst_te(X, U, open_te_rec(k, typ_fvar(X), e));
{
forall (V | V<e && X !in fv_tt(V))
ensures open_tt_rec(k, U, V) == subst_tt(X, U, open_tt_rec(k, typ_fvar(X), V));
{
lemma_subst_tt_intro_rec(X, V, U, k);
}
}
ghost method lemma_subst_te_intro(X: int, e: exp, U: typ)
requires X !in fv_te(e);
ensures open_te(e, U) == subst_te(X, U, open_te(e, typ_fvar(X)));
{
lemma_subst_te_intro_rec(X, e, U, 0);
}
ghost method {:induction e, j, i} lemma_open_ee_rec_expr_aux(e: exp, j: nat, v: exp, u: exp, i: nat)
requires i != j;
requires open_ee_rec(j, v, e) == open_ee_rec(i, u, open_ee_rec(j, v, e));
ensures e == open_ee_rec(i, u, e);
{
}
ghost method {:induction e, j, i} lemma_open_ee_rec_type_aux(e: exp, j: nat, V: typ, u: exp, i: nat)
requires open_te_rec(j, V, e) == open_ee_rec(i, u, open_te_rec(j, V, e));
ensures e == open_ee_rec(i, u, e);
{
}
ghost method lemma_open_ee_rec_expr(u: exp, e: exp, k: nat)
requires exp_lc(e);
ensures e == open_ee_rec(k, u, e);
decreases exp_size(e);
{
if (e.exp_abs?) {
var L:set<int> :| forall x :: x !in L ==> exp_lc(open_ee(e.e0, exp_fvar(x)));
var x := notin(L);
lemma_open_ee_rec_expr(u, open_ee(e.e0, exp_fvar(x)), k);
lemma_open_ee_rec_expr_aux(e.e0, 0, exp_fvar(x), u, k+1);
} else if (e.exp_tabs?) {
var L:set<int> :| forall X :: X !in L ==> exp_lc(open_te(e.te0, typ_fvar(X)));
var X := notin(L);
lemma_open_ee_rec_type_aux(e.te0, 0, typ_fvar(X), u, k);
}
}
ghost method lemma_subst_ee_fresh(x: int, u: exp, e: exp)
requires x !in fv_ee(e);
ensures e == subst_ee(x, u, e);
{
}
ghost method lemma_subst_ee_open_ee_rec(e1: exp, e2: exp, x: int, u: exp, k: nat)
requires exp_lc(u);
ensures subst_ee(x, u, open_ee_rec(k, e2, e1))
== open_ee_rec(k, subst_ee(x, u, e2), subst_ee(x, u, e1));
{
if (e1.exp_fvar? && e1.a==x) {
lemma_open_ee_rec_expr(subst_ee(x, u, e2), u, k);
}
}
ghost method lemma_subst_ee_open_ee(e1: exp, e2: exp, x: int, u: exp)
requires exp_lc(u);
ensures subst_ee(x, u, open_ee(e1, e2))
== open_ee(subst_ee(x, u, e1), subst_ee(x, u, e2));
{
lemma_subst_ee_open_ee_rec(e1, e2, x, u, 0);
}
ghost method lemma_subst_ee_open_ee_var(x: int, y: int, u: exp, e: exp)
requires y != x;
requires exp_lc(u);
ensures open_ee(subst_ee(x, u, e), exp_fvar(y)) == subst_ee(x, u, open_ee(e, exp_fvar(y)));
{
lemma_subst_ee_open_ee(e, exp_fvar(y), x, u);
}
ghost method lemma_subst_te_open_ee_rec(e1: exp, e2: exp, Z: int, P: typ, k: nat)
ensures subst_te(Z, P, open_ee_rec(k, e2, e1))
== open_ee_rec(k, subst_te(Z, P, e2), subst_te(Z, P, e1));
{
}
ghost method lemma_subst_te_open_ee(e1: exp, e2: exp, Z: int, P: typ)
ensures subst_te(Z, P, open_ee(e1, e2)) == open_ee(subst_te(Z, P, e1), subst_te(Z, P, e2));
{
lemma_subst_te_open_ee_rec(e1, e2, Z, P, 0);
}
ghost method lemma_subst_te_open_ee_var(Z: int, x: int, P: typ, e: exp)
ensures open_ee(subst_te(Z, P, e), exp_fvar(x)) == subst_te(Z, P, open_ee(e, exp_fvar(x)));
{
lemma_subst_te_open_ee(e, exp_fvar(x), Z, P);
}
ghost method lemma_subst_ee_open_te_rec(e: exp, P: typ, z: int, u: exp, k: nat)
requires exp_lc(u);
ensures subst_ee(z, u, open_te_rec(k, P, e)) == open_te_rec(k, P, subst_ee(z, u, e));
{
if (e.exp_fvar? && e.a==z) {
lemma_open_te_rec_expr(u, P, k);
}
}
ghost method lemma_subst_ee_open_te(e: exp, P: typ, z: int, u: exp)
requires exp_lc(u);
ensures subst_ee(z, u ,open_te(e, P)) == open_te(subst_ee(z, u, e), P);
{
lemma_subst_ee_open_te_rec(e, P, z, u, 0);
}
ghost method lemma_subst_ee_open_te_var(z: int, X: int, u: exp, e: exp)
requires exp_lc(u);
ensures open_te(subst_ee(z, u, e), typ_fvar(X)) == subst_ee(z, u, open_te(e, typ_fvar(X)));
{
lemma_subst_ee_open_te(e, typ_fvar(X), z, u);
}
ghost method lemma_subst_ee_intro_rec(x: int, e: exp, u: exp, k: nat)
requires x !in fv_ee(e);
ensures open_ee_rec(k, u, e) == subst_ee(x, u, open_ee_rec(k, exp_fvar(x), e));
{
}
ghost method lemma_subst_ee_intro(x: int, e: exp, u: exp)
requires x !in fv_ee(e);
ensures open_ee(e, u) == subst_ee(x, u, open_ee(e, exp_fvar(x)));
{
lemma_subst_ee_intro_rec(x, e, u, 0);
}
ghost method lemma_subst_tt_type(Z: int, P: typ, T: typ)
requires typ_lc(T);
requires typ_lc(P);
ensures typ_lc(subst_tt(Z, P, T));
decreases typ_size(T);
{
if (T.typ_all?) {
var L:set<int> :| forall X :: X !in L ==> typ_lc(open_tt(T.ty0, typ_fvar(X)));
var L' := L+{Z};
forall (X | X !in L')
ensures typ_lc(open_tt(subst_tt(Z, P, T.ty0), typ_fvar(X)));
{
lemma_subst_tt_type(Z, P, open_tt(T.ty0, typ_fvar(X)));
lemma_subst_tt_open_tt_var(Z, X, P, T.ty0);
}
}
}
ghost method lemma_subst_te_expr(Z: int, P: typ, e: exp)
requires exp_lc(e);
requires typ_lc(P);
ensures exp_lc(subst_te(Z, P, e));
decreases exp_size(e);
{
forall (V | V<e && typ_lc(V))
ensures typ_lc(subst_tt(Z, P, V));
{
lemma_subst_tt_type(Z, P, V);
}
if (e.exp_abs?) {
var L:set<int> :| forall x :: x !in L ==> exp_lc(open_ee(e.e0, exp_fvar(x)));
forall (x | x !in L)
ensures exp_lc(open_ee(subst_te(Z, P, e.e0), exp_fvar(x)));
{
lemma_subst_te_expr(Z, P, open_ee(e.e0, exp_fvar(x)));
lemma_subst_te_open_ee_var(Z, x, P, e.e0);
}
} else if (e.exp_tabs?) {
var L:set<int> :| forall X :: X !in L ==> exp_lc(open_te(e.te0, typ_fvar(X)));
var L' := L+{Z};
forall (X | X !in L')
ensures exp_lc(open_te(subst_te(Z, P, e.te0), typ_fvar(X)));
{
lemma_subst_te_expr(Z, P, open_te(e.te0, typ_fvar(X)));
lemma_subst_te_open_te_var(Z, X, P, e.te0);
}
}
}
ghost method lemma_subst_ee_expr(z: int, e1: exp, e2: exp)
requires exp_lc(e1);
requires exp_lc(e2);
ensures exp_lc(subst_ee(z, e2, e1));
decreases exp_size(e1);
{
if (e1.exp_abs?) {
var L:set<int> :| forall x :: x !in L ==> exp_lc(open_ee(e1.e0, exp_fvar(x)));
var L' := L+{z};
forall (x | x !in L')
ensures exp_lc(open_ee(subst_ee(z, e2, e1.e0), exp_fvar(x)));
{
lemma_subst_ee_expr(z, open_ee(e1.e0, exp_fvar(x)), e2);
lemma_subst_ee_open_ee_var(z, x, e2, e1.e0);
}
} else if (e1.exp_tabs?) {
var L:set<int> :| forall X :: X !in L ==> exp_lc(open_te(e1.te0, typ_fvar(X)));
forall (X | X !in L)
ensures exp_lc(open_te(subst_ee(z, e2, e1.te0), typ_fvar(X)));
{
lemma_subst_ee_expr(z, open_te(e1.te0, typ_fvar(X)), e2);
lemma_subst_ee_open_te_var(z, X, e2, e1.te0);
}
}
}
ghost method lemma_open_ee_body_e(e1: exp, e2: exp)
requires body_lc(e1);
requires exp_lc(e2);
ensures exp_lc(open_ee(e1, e2));
{
var L:set<int> :| forall x :: x !in L ==> exp_lc(open_ee(e1, exp_fvar(x)));
var L' := L+fv_ee(e1);
var x := notin(L');
lemma_subst_ee_intro(x, e1, e2);
lemma_subst_ee_expr(x, open_ee(e1, exp_fvar(x)), e2);
}
/// Lemmas
/// https://github.com/plclub/metalib/blob/master/Fsub_LetSum_Lemmas.v
ghost method {:induction E, T} lemma_typ_lc_from_wf(E: env, T: typ)
requires typ_wf(E, T);
ensures typ_lc(T);
decreases typ_size(T);
{
}
ghost method lemma_wf_typ_weakening(T: typ, E: env, F: env, G: env)
requires typ_wf(env_concat(G, E), T);
requires env_uniq(env_concat3(G, F, E));
ensures typ_wf(env_concat3(G, F, E), T);
decreases typ_size(T);
{
if (T.typ_all?) {
var L:set<int> :| forall X :: X !in L ==> typ_wf(env_plus_var(X, env_concat(G, E)), open_tt(T.ty0, typ_fvar(X)));
var L' := L+env_dom(G)+env_dom(F)+env_dom(E);
forall (X | X !in L')
ensures typ_wf(env_plus_var(X, env_concat3(G, F, E)), open_tt(T.ty0, typ_fvar(X)));
{
env_plus_concat(X, G, E);
env_plus_concat3(X, G, F, E);
env_concat3_dom(G, F, E);
env_plus_uniq(X, env_concat3(G, F, E));
lemma_wf_typ_weakening(open_tt(T.ty0, typ_fvar(X)), E, F, env_plus_var(X, G));
}
}
}
ghost method lemma_wf_typ_weaken_head(T: typ, E: env, F: env)
requires typ_wf(E, T);
requires env_uniq(env_concat(F, E));
ensures typ_wf(env_concat(F, E), T);
{
env_concat3_empty(F, E);
env_concat_empty(E);
lemma_wf_typ_weakening(T, E, F, Env([]));
}
ghost method lemma_wf_typ_strengthening(E: env, F: env, x: int, U: typ, T: typ)
requires typ_wf(env_concat3(F, Env([bd_typ(x, U)]), E), T);
ensures typ_wf(env_concat(F, E), T);
decreases typ_size(T);
{
if (T.typ_all?) {
var L:set<int> :| forall X :: X !in L ==> typ_wf(env_plus_var(X, env_concat3(F, Env([bd_typ(x, U)]), E)), open_tt(T.ty0, typ_fvar(X)));
var L' := L;
forall (X | X !in L')
ensures typ_wf(env_plus_var(X, env_concat(F, E)), open_tt(T.ty0, typ_fvar(X)));
{
env_plus_concat3(X, F, Env([bd_typ(x, U)]), E);
env_plus_concat(X, F, E);
lemma_wf_typ_strengthening(E, env_plus_var(X, F), x, U, open_tt(T.ty0, typ_fvar(X)));
}
}
}
function subst_bd(Z: int, P: typ, bd: binding): binding
ensures bd.bd_var? ==> subst_bd(Z, P, bd)==bd;
ensures bd.bd_typ? ==> subst_bd(Z, P, bd)==bd_typ(bd.x, subst_tt(Z, P, bd.ty));
ensures bd_dom(bd)==bd_dom(subst_bd(Z, P, bd));
{
match bd
case bd_var(X) => bd_var(X)
case bd_typ(x, T) => bd_typ(x, subst_tt(Z, P, T))
}
function subst_bds(Z: int, P: typ, bds: seq<binding>): seq<binding>
ensures forall X :: bd_var(X) in bds ==> bd_var(X) in subst_bds(Z, P, bds);
ensures forall x :: bds_lookup(x, bds).Some? ==> bds_lookup(x, subst_bds(Z, P, bds)).Some? && subst_tt(Z, P, bds_lookup(x, bds).get)==bds_lookup(x, subst_bds(Z, P, bds)).get;
ensures bds_dom(bds)==bds_dom(subst_bds(Z, P, bds));
{
if (|bds|==0) then [] else
[subst_bd(Z, P, bds[0])]+subst_bds(Z, P, bds[1..])
}
function subst_env(Z: int, P: typ, E: env): env
ensures forall X :: env_has_var(X, E) ==> env_has_var(X, subst_env(Z, P, E));
ensures forall x :: env_lookup(x, E).Some? ==> env_lookup(x, subst_env(Z, P, E)).Some? && subst_tt(Z, P, env_lookup(x, E).get)==env_lookup(x, subst_env(Z, P, E)).get;
ensures env_dom(E)==env_dom(subst_env(Z, P, E));
{
Env(subst_bds(Z, P, E.bds))
}
ghost method lemma_wf_typ_subst_tb(F: env, E: env, Z: int, P: typ, T: typ)
requires typ_wf(env_concat3(F, Env([bd_var(Z)]), E), T);
requires typ_wf(E, P);
requires env_uniq(env_concat(subst_env(Z, P, F), E));
ensures typ_wf(env_concat(subst_env(Z, P, F), E), subst_tt(Z, P, T));
decreases typ_size(T);
{
if (T.typ_fvar?) {
if (T.a == Z) {
assert subst_tt(Z, P, T)==P;
lemma_wf_typ_weaken_head(P, E, subst_env(Z, P, F));
}
} else if (T.typ_all?) {
var L:set<int> :| forall X :: X !in L ==> typ_wf(env_plus_var(X, env_concat3(F, Env([bd_var(Z)]), E)), open_tt(T.ty0, typ_fvar(X)));
var L' := L+env_dom(E)+env_dom(F)+{Z};
forall (X | X !in L')
ensures typ_wf(env_plus_var(X, env_concat(subst_env(Z, P, F), E)), open_tt(subst_tt(Z, P, T.ty0), typ_fvar(X)));
{
env_plus_concat3(X, F, Env([bd_var(Z)]), E);
env_plus_concat(X, subst_env(Z, P, F), E);
env_concat_dom(subst_env(Z, P, F), E);
env_plus_uniq(X, env_concat(subst_env(Z, P, F), E));
lemma_wf_typ_subst_tb(env_plus_var(X, F), E, Z, P, open_tt(T.ty0, typ_fvar(X)));
lemma_typ_lc_from_wf(E, P);
lemma_subst_tt_open_tt_var(Z, X, P, T.ty0);
}
}
}
ghost method {:timeLimit 30} lemma_wf_typ_open(E: env, U: typ, T0: typ)
requires env_uniq(E);
requires typ_wf(E, typ_all(T0));
requires typ_wf(E, U);
ensures typ_wf(E, open_tt(T0, U));
{
var L:set<int> :| forall X :: X !in L ==> typ_wf(env_plus_var(X, E), open_tt(T0, typ_fvar(X)));
var L' := L+fv_tt(T0);
var X := notin(L');
lemma_subst_tt_intro(X, T0, U);
env_concat_empty(E);
env_concat3_empty(Env([bd_var(X)]), E);
lemma_wf_typ_subst_tb(Env([]), E, X, U, open_tt(T0, typ_fvar(X)));
}
ghost method lemma_env_uniq_from_wf(E: env)
requires env_wf(E);
ensures env_uniq(E);
{
}
ghost method lemma_typ_wf_from_binds(x: int, U: typ, E: env)
requires env_wf(E);
requires env_lookup(x, E) == Some(U);
ensures typ_wf(E, U);
decreases E.bds;
{
if (|E.bds|==0) {
} else {
if (E.bds[0].bd_typ? && E.bds[0].x==x) {
assert U == E.bds[0].ty;
} else {
lemma_typ_wf_from_binds(x, U, Env(E.bds[1..]));
}
lemma_wf_typ_weaken_head(U, Env(E.bds[1..]), Env([E.bds[0]]));
env_concat_split(E);
}
}
ghost method lemma_wf_typ_from_wf_env_typ(x: int, T: typ, E: env)
requires env_wf(env_extend(x, T, E));
ensures typ_wf(E, T);
{
}
ghost method lemma_env_wf_strengthening(x: int, T: typ, E: env, F: env)
requires env_wf(env_concat3(F, Env([bd_typ(x, T)]), E));
ensures env_wf(env_concat(F, E));
decreases F.bds;
{
if (|F.bds|==0) {
env_concat3_empty(Env([bd_typ(x, T)]), E);
env_concat_empty(E);
} else {
env_concat3_split(F, Env([bd_typ(x, T)]), E);
lemma_env_wf_strengthening(x, T, E, Env(F.bds[1..]));
env_concat2_split(F, E);
bds_concat3_dom(F.bds[1..], [bd_typ(x, T)], E.bds);
bds_concat_dom(F.bds[1..], E.bds);
if (F.bds[0].bd_typ?) {
lemma_wf_typ_strengthening(E, Env(F.bds[1..]), x, T, F.bds[0].ty);
}
}
}
ghost method lemma_bds_wf_subst_tb(Z: int, P: typ, E: seq<binding>, F: seq<binding>)
requires bds_wf(F+[bd_var(Z)]+E);
requires typ_wf(Env(E), P);
ensures bds_wf(subst_bds(Z, P, F)+E);
decreases F;
{
if (|F|==0) {
assert F+[bd_var(Z)]+E==[bd_var(Z)]+E;
assert subst_bds(Z, P, F)+E==E;
} else {
assert (F+[bd_var(Z)]+E)[1..]==F[1..]+[bd_var(Z)]+E;
lemma_bds_wf_subst_tb(Z, P, E, F[1..]);
assert (subst_bds(Z, P, F)+E)[1..]==subst_bds(Z, P, F[1..])+E;
assert (subst_bds(Z, P, F)+E)[0]==subst_bd(Z, P, F[0]);
var x;
if (F[0].bd_typ?) {
lemma_wf_typ_subst_tb(Env(F[1..]), Env(E), Z, P, F[0].ty);
assert typ_wf(env_concat(subst_env(Z, P, Env(F[1..])), Env(E)), subst_tt(Z, P, F[0].ty));
assert env_concat(subst_env(Z, P, Env(F[1..])), Env(E))==Env(subst_bds(Z, P, F[1..])+E);
x := F[0].x;
} else {
x := F[0].X;
}
bds_concat_dom(F[1..], E);
bds_concat_dom(subst_bds(Z, P, F[1..]), E);
bds_dom_split(x, F[1..]+[bd_var(Z)], E);
bds_dom_split(x, F[1..], [bd_var(Z)]);
assert x !in bds_dom(F[1..]+E);
assert bds_dom(subst_bds(Z, P, F[1..])+E)==bds_dom(F[1..]+E);
assert bd_wf(subst_bd(Z, P, F[0]), subst_bds(Z, P, F[1..])+E);
}
}
ghost method lemma_env_wf_subst_tb(Z: int, P: typ, E: env, F: env)
requires env_wf(env_concat3(F, Env([bd_var(Z)]), E));
requires typ_wf(E, P);
ensures env_wf(env_concat(subst_env(Z, P, F), E));
{
lemma_bds_wf_subst_tb(Z, P, E.bds, F.bds);
}
ghost method {:induction T, k} lemma_notin_fv_tt_open_rec(Y: int, X: int, T: typ, k: nat)
requires X !in fv_tt(open_tt_rec(k, typ_fvar(Y), T));
ensures X !in fv_tt(T);
decreases typ_size(T);
{
}
ghost method lemma_notin_fv_tt_open(Y: int, X: int, T: typ)
requires X !in fv_tt(open_tt(T, typ_fvar(Y)));
ensures X !in fv_tt(T);
{
lemma_notin_fv_tt_open_rec(Y, X, T, 0);
}
ghost method lemma_notin_fv_wf(E: env, X: int, T: typ)
requires typ_wf(E, T);
requires X !in env_dom(E);
ensures X !in fv_tt(T);
decreases typ_size(T);
{
if (T.typ_all?) {
var L:set<int> :| forall Y :: Y !in L ==> typ_wf(env_plus_var(Y, E), open_tt(T.ty0, typ_fvar(Y)));
var L' := L+{X};
var Y := notin(L');
lemma_notin_fv_wf(env_plus_var(Y, E), X, open_tt(T.ty0, typ_fvar(Y)));
lemma_notin_fv_tt_open(Y, X, T.ty0);
}
}
ghost method lemma_map_subst_tb_id(G: env, Z: int, P: typ)
requires env_wf(G);
requires Z !in env_dom(G);
ensures G==subst_env(Z, P, G);
decreases G.bds;
{
if (|G.bds|==0) {
} else {
if (G.bds[0].bd_typ?) {
lemma_notin_fv_wf(Env(G.bds[1..]), Z, G.bds[0].ty);
lemma_subst_tt_fresh(Z, P, G.bds[0].ty);
}
env_concat_split(G);
lemma_map_subst_tb_id(Env(G.bds[1..]), Z, P);
}
}
/// Regularity
ghost method {:timeLimit 20} lemma_typing_regular(E: env, e: exp, T: typ)