Add new BLEStringCharacateristic type

[sandeepmistry]

Resolves #4.

Example usage sketch:

#include <ArduinoBLE.h>

BLEService stringService("19B10000-0001-537E-4F6C-D104768A1214"); // BLE String Service
BLEStringCharacteristic stringCharacteristic("19B10001-0001-537E-4F6C-D104768A1214", BLERead | BLEWrite, 512);

void setup() {
  Serial.begin(9600);
  while (!Serial);

  // begin initialization
  if (!BLE.begin()) {
    Serial.println("starting BLE failed!");

    while (1);
  }

  // set advertised local name and service UUID:
  BLE.setLocalName("String");
  BLE.setAdvertisedService(stringService);

  // add the characteristic to the service
  stringService.addCharacteristic(stringCharacteristic);

  // add service
  BLE.addService(stringService);

  // set the initial value for the characeristic:
  stringCharacteristic.writeValue("hello");

  // start advertising
  BLE.advertise();

  Serial.println("BLE String Peripheral");
}

void loop() {
  // listen for BLE peripherals to connect:
  BLEDevice central = BLE.central();

  // if a central is connected to peripheral:
  if (central) {
    Serial.print("Connected to central: ");
    // print the central's MAC address:
    Serial.println(central.address());

    // while the central is still connected to peripheral:
    while (central.connected()) {
      if (stringCharacteristic.written()) {
        Serial.println("stringCharacteristic written, new value = ");

        String value = stringCharacteristic.value();

        Serial.println(value);
      }
    }

    // when the central disconnects, print it out:
    Serial.print(F("Disconnected from central: "));
    Serial.println(central.address());
  }
}

[alex-taffe]

This seems to not be documented here yet

[per1234]

This seems to not be documented here yet

The deficiency is now tracked here: #349