[New Workflow] Flye_denovo to replace DragonFlye

tasks/alignment/task_bwa.wdl

@@ -153,4 +153,47 @@ task bwa {
     preemptible: 0
     maxRetries: 3
   }
-}
+}
+
+task bwa_all {
+  input {
+    File draft_assembly_fasta
+    File read1
+    File read2
+    String samplename
+
+    Int cpu = 6
+    Int disk_size = 100
+    String docker = "us-docker.pkg.dev/general-theiagen/staphb/bwa:0.7.18"
+    Int memory = 16
+  }
+  command <<<
+    bwa &> BWA_HELP
+    grep "Version" BWA_HELP | cut -d" " -f2 > BWA_VERSION
+
+    if [[ ! -f "~{draft_assembly_fasta}.bwt" ]]; then
+      echo "Indexing reference genome: ~{draft_assembly_fasta}"
+      bwa index ~{draft_assembly_fasta}
+    else
+      echo "Reference genome is already indexed: ~{draft_assembly_fasta}"
+    fi
+
+    bwa mem -t ~{cpu} -a ~{draft_assembly_fasta} ~{read1} > ~{samplename}_R1.sam
+    bwa mem -t ~{cpu} -a ~{draft_assembly_fasta} ~{read2} > ~{samplename}_R2.sam
+
+  >>>
+  output {
+    File read1_sam = "~{samplename}_R1.sam"
+    File read2_sam = "~{samplename}_R2.sam"
+    String bwa_version = read_string("BWA_VERSION")
+  }
+  runtime {
+    docker: "~{docker}"
+    memory: "~{memory} GB"
+    cpu: "~{cpu}"
+    disks:  "local-disk " + disk_size + " SSD"
+    disk: disk_size + " GB"
+    maxRetries: 3
+    preemptible: 0
+  }
+}

tasks/assembly/task_bandageplot.wdl

@@ -0,0 +1,30 @@
+version 1.0
+
+task bandage_plot {
+    input {
+      File assembly_graph_gfa
+      String samplename
+      Int cpu = 2
+      Int memory = 4
+      Int disk_size = 10
+      String docker = "us-docker.pkg.dev/general-theiagen/staphb/bandage:0.8.1"
+    }
+    command <<< 
+      set -euo pipefail
+      Bandage --version | tee VERSION
+      Bandage image ~{assembly_graph_gfa} ~{samplename}_bandage_plot.png
+    >>>
+    output {
+      File plot = "~{samplename}_bandage_plot.png"
+      String bandage_version = read_string("VERSION")
+    }
+    runtime {
+      docker: "~{docker}"
+      cpu: cpu
+      memory: "~{memory} GB"
+      disks: "local-disk " + disk_size + " HDD"
+      disk: disk_size + " GB"
+      maxRetries: 1
+      preemptible: 0
+  }
+}

tasks/assembly/task_dnaapler.wdl

@@ -0,0 +1,72 @@
+version 1.0
+
+task dnaapler_all {
+  input {
+    File input_fasta
+    String samplename
+    String dmaapler_mode = "all" # The mode of reorientation to execute (default: 'all')
+    Int cpu = 4
+    Int disk_size = 100
+    Int memory = 16
+    String docker = "us-docker.pkg.dev/general-theiagen/staphb/dnaapler:1.0.1"
+  }
+  command <<< 
+    set -euo pipefail
+
+    # Check input FASTA is valid
+    echo "Validating input FASTA file..."
+    if ! grep -q "^>" ~{input_fasta}; then
+      echo "ERROR: Input file ~{input_fasta} is not in FASTA format." >&2
+      exit 1
+    else
+      echo "Input FASTA file is valid."
+    fi
+
+    # dnaapler version
+    dnaapler --version | tee VERSION
+
+    # Create a subdirectory for dnaapler outputs
+    output_dir="dnaapler_output"
+    mkdir -p "$output_dir"
+    echo "Output directory created: $output_dir"
+
+    # Run dnaapler with the 'all' subcommand
+    echo "Running dnaapler..."
+    dnaapler ~{dmaapler_mode} \
+      -i ~{input_fasta} \
+      -o "$output_dir" \
+      -p ~{samplename} \
+      -t ~{cpu} \
+      -f || {
+        echo "ERROR: dnaapler command failed. Check logs for details." >&2
+        exit 1
+      }
+
+    echo "dnaapler command completed successfully."
+
+    # Check if output FASTA file exists
+    if [[ ! -f "$output_dir"/~{samplename}_reoriented.fasta ]]; then
+      echo "ERROR: Expected output file not found: $output_dir/~{samplename}_reoriented.fasta" >&2
+      exit 1
+    fi
+
+    # Move the final reoriented FASTA file to the task's working directory
+    echo "Moving output FASTA file to working directory..."
+    mv "$output_dir"/~{samplename}_reoriented.fasta .
+
+    echo "dnaapler task completed successfully for sample: ~{samplename}"
+  >>>
+  output {
+    File reoriented_fasta = "~{samplename}_reoriented.fasta"
+    String dnaapler_version = read_string("VERSION")
+  }
+  runtime {
+    docker: "~{docker}"
+    cpu: cpu
+    memory: "~{memory} GB"
+    disks: "local-disk " + disk_size + " SSD"
+    disk: disk_size + " GB"
+    maxRetries: 3
+    preemptible: 0
+  }
+}

tasks/assembly/task_flye.wdl

@@ -0,0 +1,90 @@
+version 1.0
+
+task flye {
+  input {
+    File read1
+    String samplename
+
+    # data type options; by default, uses --nano-raw
+    Boolean ont_corrected = false
+    Boolean ont_high_quality = false
+    Boolean pacbio_raw = false
+    Boolean pacbio_corrected = false
+    Boolean pacbio_hifi = false
+
+    Int? genome_length # requires `asm_coverage`
+    Int? asm_coverage # reduced coverage for initial disjointig assembly
+
+    Int flye_polishing_iterations = 1
+    Int? minimum_overlap
+
+    Float? read_error_rate
+    Boolean uneven_coverage_mode = false
+    Boolean keep_haplotypes = false
+    Boolean no_alt_contigs = false
+    Boolean scaffold = false
+
+    String? additional_parameters    # Any extra Flye-specific parameters
+
+    Int cpu = 4
+    Int disk_size = 100
+    String docker = "us-docker.pkg.dev/general-theiagen/staphb/flye:2.9.4"
+    Int memory = 32
+  }
+  command <<<
+    set -euo pipefail
+    flye --version | tee VERSION
+
+    # determine read type
+    if ~{ont_corrected}; then
+      READ_TYPE="--nano-corr"
+    elif ~{ont_high_quality}; then
+      READ_TYPE="--nano-hq"
+    elif ~{pacbio_raw}; then
+      READ_TYPE="--pacbio-raw"
+    elif ~{pacbio_corrected}; then
+      READ_TYPE="--pacbio-corr"
+    elif ~{pacbio_hifi}; then
+      READ_TYPE="--pacbio-hifi"
+    else
+      READ_TYPE="--nano-raw"
+    fi
+
+    # genome size parameter requires asm_coverage
+    flye \
+      ${READ_TYPE} ~{read1} \
+      --iterations ~{flye_polishing_iterations} \
+      ~{"--min-overlap" + minimum_overlap} \
+      ~{if defined(asm_coverage) then "--genome-size " + genome_length else ""} \
+      ~{"--asm-coverage " + asm_coverage} \
+      ~{"--read-error " + read_error_rate} \
+      ~{true="--meta" false="" uneven_coverage_mode} \
+      ~{true="--keep-haplotypes" false="" keep_haplotypes} \
+      ~{true="--no-alt-contigs" false="" no_alt_contigs} \
+      ~{true="--scaffold" false="" scaffold} \
+      ~{"--extra-params " + additional_parameters } \
+      --threads ~{cpu} \
+      --out-dir .
+
+    mv assembly.fasta ~{samplename}.assembly.fasta
+    mv assembly_info.txt ~{samplename}.assembly_info.txt
+    mv assembly_graph.gfa ~{samplename}.assembly_graph.gfa
+
+  >>>
+  output {
+    File assembly_fasta = "~{samplename}.assembly.fasta"
+    File assembly_graph_gfa = "~{samplename}.assembly_graph.gfa" 
+    File assembly_info = "~{samplename}.assembly_info.txt" 
+    String flye_version = read_string("VERSION")
+    String flye_docker = "~{docker}"
+  }
+  runtime {
+    docker: "~{docker}"
+    cpu: cpu
+    memory: "~{memory} GB"
+    disks: "local-disk " + disk_size + " SSD"
+    disk: disk_size + " GB"
+    maxRetries: 3
+    preemptible: 0
+  }
+}